Private Msg_BackPressed As Boolean = False

AddHandler txtWO_Msg.ChatElement.InputTextBox.TextBoxItem.TextBoxControl.TextChanged, AddressOf txtWO_Msg_TextBoxControl_TextChanged
AddHandler txtWO_Msg.ChatElement.InputTextBox.TextBoxItem.TextBoxControl.PreviewKeyDown, AddressOf txtWO_Msg_TextBoxControl_PreviewKeyDown

Private Sub txtWO_Msg_TextBoxControl_TextChanged(sender As Object, e As EventArgs)
    'Cancel if we pressed the backspace
    If Msg_BackPressed Then Msg_BackPressed = False : Exit Sub

    Dim t As TextBox = TryCast(sender, TextBox)

    If t IsNot Nothing Then

        If t.Text.Length > 0 AndAlso t.Text.Contains("@") Then

            'Here we'll get the text strictly after the @ symbol, wherever they are in the textbox
            Dim User As String = ""
            Dim TmpStr As String = Mid(t.Text, 1, t.SelectionStart)
            Dim Index As Integer = TmpStr.LastIndexOf("@")
            Dim CA As Char() = TmpStr.ToCharArray()
            For I As Integer = Index + 1 To CA.Length - 1
                If CA(I) = " " Then Exit Sub
                User &= CA(I)
            Next

            'If it's already typed out, don't bother auto-completing
            If Not GeneralAccountDataStrList.Contains(User) Then
                'Loop through the list of string and find one that resembles what we've typed so far
                For I As Integer = 0 To GeneralAccountDataStrList.Count - 1
                    If GeneralAccountDataStrList(I).Contains(User) And User.Length > 0 Then
                        'Here we get the portion of the string that will be added and highlighted
                        Dim TxtAdd As String = Replace(GeneralAccountDataStrList(I), User, "", 1, 1)
                        Dim Start As Integer = t.SelectionStart
                        'Insert the string at the current caret location
                        t.Text = t.Text.Insert(Start, TxtAdd)
                        t.SelectionStart = Start
                        'Make sure we select the suggested text so the user can easily replace/remove it
                        t.SelectionLength = TxtAdd.Length
                        Exit For
                    End If
                Next
            End If
        End If
    End If
End Sub

Private Sub txtWO_Msg_TextBoxControl_PreviewKeyDown(sender As Object, e As PreviewKeyDownEventArgs)
    Dim t As TextBox = TryCast(sender, TextBox)

    If t IsNot Nothing Then

        'If the user pressed Backspace or Delete, we need to cancel the suggestion algorithm
        Msg_BackPressed = e.KeyCode = Keys.Back Or e.KeyCode = Keys.Delete

        'If we pressed tab, accept the suggestion (Pressing enter just submits the entire message)
        If e.KeyCode = Keys.Tab Then
            If t.SelectionLength > 0 Then
                t.SelectionStart += t.SelectionLength
                t.SelectionLength = 0
            End If
        End If
            
    End If
End Sub